• 幕客老师召集小伙伴
  • 运维高手36项修炼
  • python自动化运维项目实战
  • nginx从入门到实战
  • 阿里云与Centos7实战

Shell三剑客之AWK用法

文本处理 awk
========================================================

一、awk简介
awk 是一种编程语言,用于在linux/unix下对文本和数据进行处理。数据可以来自标准输入、一个
或多个文件,或其它命令的输出。它支持用户自定义函数和动态正则表达式等先进功能,是linux/unix
下的一个强大编程工具。它在命令行中使用,但更多是作为脚本来使用。
awk的处理文本和数据的方式是这样的,它逐行扫描文件,从第一行到最后一行,寻找匹配的特定
模式的行,并在这些行上进行你想要的操作。如果没有指定处理动作,则把匹配的行显示到标准输出(
屏幕),如果没有指定模式,则所有被操作所指定的行都被处理。awk分别代表其作者姓氏的第一个字
母。因为它的作者是三个人,分别是Alfred Aho、Brian Kernighan、Peter Weinberger。gawk是
awk的GNU版本,它提供了Bell实验室和GNU的一些扩展。

二、awk的两种形式语法格式

注意:括号外是单引号
awk [options] ‘commands’ filename
awk [options] -f awk-script-file filename

command |awk ‘pattern’ 
command |awk ‘{action}’ 
command |awk ‘pattern {action}’ 示例:df -P |awk ‘$4 > 25000′

==options:
-F 定义字段分隔符,默认的分隔符是空格或制表符(tab)

==command:
BEGIN{}       {}         END{}
读前处理        行处理 处理后

==awk命令格式:
awk ‘pattern’ filename 示例:awk -F: ‘/root/’ /etc/passwd 
awk ‘{action}’ filename 示例:awk -F: ‘{print $1}’ /etc/passwd 
awk ‘pattern {action}’ filename 示例:awk -F: ‘/root/{print $1,$3}’ /etc/passwd 
示例:awk ‘BEGIN{FS=”:”} /root/{print $1,$3}’ /etc/passwd

========================================================
awk工作原理
# awk -F: ‘{print $1,$3}’ /etc/passwd
(1)awk使用一行作为输入,并将这一行赋给内部变量$0,每一行也可称为一个记录,以换行符结束
(2)然后,行被空格分解成字段(或域),每个字段存储在已编号的变量中,从$1开始,最多达100个字段
(3)awk如何知道用空格来分隔字段的呢? 因为有一个内部变量FS来确定字段分隔符。初始时,FS赋为空格
(4)awk打印字段时,将以设置的方法使用print函数打印,awk在打印的字段间加上空格,因为$1,$3之间
有一个逗号。逗号比较特殊,它映射为另一个内部变量,称为输出字段分隔符OFS,OFS默认为空格
(5)awk输出之后,将从文件中获取另一行,并将其存储在$0中,覆盖原来的内容,然后将新的字符串分隔
成字段并进行处理。该过程将持续到所有行处理完毕
========================================================

==记录与字段相关内部变量:
$0: awk变量$0保存当前记录的内容 # awk -F: ‘{print $0}’ /etc/passwd
NR: 记录号,每处理完一条记录,NR值加1 # awk -F: ‘{print NR, $0}’ /etc/passwd
NF: 保存记录的字段数,$1,$2…$100 # awk -F: ‘{print $0,NF}’ /etc/passwd
$NF: 最后行内容。                                    # awk -F: ‘{print $0,$NF}’ /etc/passwd
FS: 输入字段分隔符,默认空格 # awk -F: ‘/alice/{print $1, $3}’ /etc/passwd
# awk -F'[ :\t]’ ‘{print $1,$2,$3}’ /etc/passwd 
# awk ‘BEGIN{FS=”:”} {print $1,$3}’ /etc/passwd
OFS:输出字段分隔符 # awk -F: ‘/alice/{print $1,$2,$3,$4}’ /etc/passwd
# awk -F: ‘BEGIN{OFS=”+++”} /^root/{print $1,$2,$3,$4}’ /etc/passwd

=======================================================

==格式化输出:
print函数
# date |awk ‘{print “Month: “$2 “\nYear: “$6}’
# awk -F: ‘{print “username is: ” $1 “\t uid is: “$3}’ /etc/passwd
# awk -F: ‘/root/{print “\t\tusername and uid: ” $1,$3 “!”}’ /etc/passwd

printf函数
# awk -F: ‘{printf “%-15s %-10s %-15s\n”, $1,$2,$3}’  /etc/passwd
# awk -F: ‘{printf “|%-15s| %-10s| %-15s|\n”, $1,$2,$3}’ /etc/passwd

%s 字符类型
%d 数值类型
占15格的字符串
– 表示左对齐,默认是右对齐
printf默认不会在行尾自动换行,加\n
========================================================

三、awk模式和动作
任何awk语句都由模式和动作组成。模式部分决定动作语句何时触发及触发事件。处理即对数据进行的操作。
如果省略模式部分,动作将时刻保持执行状态。模式可以是任何条件语句或复合语句或正则表达式。模式包括两
个特殊字段 BEGIN和END。使用BEGIN语句设置计数和打印头。BEGIN语句使用在任何文本浏览动作之前,之
后文本浏览动作依据输入文本开始执行。END语句用来在awk完成文本浏览动作后打印输出文本总数和结尾状态。

模式可以是:

==正则表达式:
# awk -F: ‘/alice/{print $1,$3}’ /etc/passwd

匹配整行:
# awk ‘/^alice/’  /etc/passwd
# awk ‘$0 ~ /^alice/’  /etc/passwd

匹配操作符:匹配操作符(~)用于对记录或字段的表达式进行匹配
# awk ‘$0 ~ /^alice/’  /etc/passwd
# awk ‘$1 ~ /^alice/’  /etc/passwd
# awk ‘$7 !~ /bash$/’  /etc/passwd

 练习:统计当前系统中nologin的用户,并且打印出用户名、UID.
 awk -F: ‘$NF ~ /nologin$/{print “Username:”$1,”UID:”$3,$7}’ /etc/passwd
 
==比较表达式:
比较表达式采用对文本进行比较,只有当条件为真,才执行指定的动作。比较表达式使用关系运算符,
用于比较数字与字符串。

关系运算符
运算符 含义 示例
< 小于 x<y
<= 小于或等于 x<=y
== 等于 x==y
!= 不等于 x!=y
>= 大于等于 x>=y
> 大于 x>y
~ 正则表达式匹配 x~/y/
!~ 正则表达式不匹配 x!~/y/

示例:
# awk -F: ‘$3 == 0′ /etc/passwd
# awk -F: ‘$3 < 10′ /etc/passwd
# awk -F: ‘$7 == “/bin/bash”‘ /etc/passw
# awk -F: ‘$1 == “root” ‘ /etc/passwd

==条件表达式:
# awk -F: ‘{if($3>300) print $0}’ /etc/passwd
# awk -F: ‘{if($3>300) {print $0}}’ /etc/passwd
# awk -F: ‘{if($3>300) {print $3} else{print $1}}’ /etc/passwd

# awk -F: ‘{if($3>300) {max=$3;print max} else{max=$1;print max}}’ /etc/passwd
# awk -F: ‘{max=($3>300) ? $3 : $1; print max}’ /etc/passwd

# awk -F: ‘{if($3>$4) {max=$3;print max} else{max=$4; print max}}’ /etc/passwd
# awk -F: ‘{max=($3 > $4) ? $3: $4; print max}’ /etc/passwd 
相当于:
if ($3 > $4)
max=$3
else
max=$4

==算术运算:+ – * / %(模) ^(幂2^3)
可以在模式中执行计算,awk都将按浮点数方式执行算术运算
# awk -F: ‘$3 * 10 > 500′ /etc/passwd

==逻辑操作符和复合模式
&& 逻辑与 a&&b
|| 逻辑或 a||b
! 逻辑非 !a
# awk ‘$2 > 5 && $2 <= 15′ filename
# awk ‘$3 == 100 || $4 > 50′ filename
# awk ‘!($2 < 100 && $3 < 20)’ filename

==范围模式
# awk ‘/Tom/,/Suzanne/’ filename

awk示例:
# awk ‘/west/’ datafile
# awk ‘/^north/’ datafile
# awk ‘/^(no|so)/’ datafile
# awk ‘{print $3,$2}’ datafile
# awk ‘{print $3 $2}’ datafile
# awk ‘{print $0}’ datafile
# awk ‘{print “Number of fields: “NF}’ datafile
# awk ‘/northeast/{print $3,$2}’ datafile
# awk ‘/E/’ datafile
# awk ‘/^[ns]/{print $1}’ datafile
# awk ‘$5 ~ /\.[7-9]+/’ datafile
# awk ‘$2 !~ /E/{print $1,$2}’ datafile
# awk ‘$3 ~ /^Joel/{print $3 ” is a nice guy.”}’ datafile
# awk ‘$8 ~ /[0-9][0-9]$/{print $8}’ datafile
# awk ‘$4 ~ /Chin$/{print “The price is $” $8 “.”}’ datafile
# awk ‘/Tj/{print $0}’ datafile
# awk ‘{print $1}’ datafile2 
# awk -F: ‘{print $1}’ datafile2
# awk ‘{print “Number of fields: “NF}’ datafile2
# awk -F: ‘{print “Number of fields: “NF}’ datafile2
# awk -F”[ :]” ‘{print $1,$2}’ datafile2
   
# awk ‘$7 == 5′ datafile
# awk ‘$2 == “CT” {print $1, $2}’ datafile
# awk ‘$7 != 5′ datafile
# awk ‘$7 < 5 {print $4, $7}’ datafile
# awk ‘$6 > .9 {print $1,$6}’ datafile
# awk ‘$8 <= 17 {print $8}’ datafile
# awk ‘$8 >= 17 {print $8}’ datafile
# awk ‘$8 > 10 && $8 < 17′ datafile
# awk ‘$2 == “NW” || $1 ~ /south/ {print $1, $2}’ datafile
# awk ‘!($8 == 13){print $8}’ datafile
# awk ‘/southem/{print $5 + 10}’ datafile

# awk ‘/southem/{print $8 + 10}’ datafile
# awk ‘/southem/{print $5 + 10.56}’ datafile
# awk ‘/southem/{print $8 – 10}’ datafile
# awk ‘/southem/{print $8 / 2 }’ datafile
# awk ‘/southem/{print $8 / 3 }’ datafile
# awk ‘/southem/{print $8 * 2 }’ datafile
# awk ‘/southem/{print $8 % 2 }’ datafile

# awk ‘$3 ~ /^Suan/ {print “Percentage: “$6 + .2   ” Volume: ” $8}’ datafile
# awk ‘/^western/,/^eastern/’ datafile
# awk -F: ‘/^roo/,/^a/’ /etc/passwd   //打印出以配备root行到匹配a开头行的所有行
# awk ‘{print ($7 > 4 ? “high “$7 : “low “$7)}’ datafile //条件运算符
# awk ‘$3 == “Chris” {$3 = “Christian”; print}’ datafile //赋值运算符
# awk ‘/Derek/ {$8 += 12; print $8}’ datafile //$8 += 12等价于$8 = $8 + 12
# awk ‘{$7 %= 3; print $7}’ datafile //$7 %= 3等价于$7 = $7 % 3 

练习:提取出本机的IP,并且加1,然后替换掉ifcfg-eth0的对应配置行,例子为192.168.1.55,做一个运算+1 ,及把我的IP配置改为192.168.1.56. 
awk -F’.’ ‘{OFS=’.’}/^IPADDR/{print $1,$2,$3,$4+1}’ /etc/sysconfig/network-scripts/ifcfg-eth0
awk -F’.’ ‘{OFS=”.”}/^IPADDR/{print $1,$2,$3,$4+1}’ /etc/sysconfig/network-scripts/ifcfg-eth0

四、awk流程控制
==条件判断
if语句:
格式
{if(表达式){语句;语句;…}}
awk -F: ‘{if($3==0) print $1 ” is administrator.”}’ /etc/passwd
awk -F: ‘{if($3>0 && $3<500){count++; print $1}} END{print count}’ /etc/passwd //统计系统用户数

if…else语句:
格式
{if(表达式){语句;语句;…}else{语句;语句;…}}
awk -F: ‘{if($3==0){print $1} else {print $7}}’ /etc/passwd
awk -F: ‘{if($3>0) {count++} else{i++}’ /etc/passwd
awk -F: ‘{if($3>0){count++} else{i++}} END{print “管理员个数: “i “\n系统用户数: “count}’ /etc/passwd

if…else if…else语句:
格式
{if(表达式){语句;语句;…}else if(表达式){语句;语句;…}else if(表达式){语句;语句;…}else{语句;语句;…}}
awk -F: ‘{if($3==0){i++} else if($3>499){k++} else{j++}} END{print i; print k; print j}’ /etc/passwd
awk -F: ‘{if($3==0){i++} else if($3>499){k++} else{j++}} END{print “管理员个数: “i; print “普通用个数: “k; print “系统用户: “j}’ /etc/passwd 

==循环
while:
awk -F: ‘{i=1; while(i<=10) {print $0;  i++}}’ /etc/passwd //将每行打印10次

for:
awk -F: ‘{for(i=1;i<=10;i++) print $0}’ /etc/passwd //将每行打印10次

==数组
# awk -F: ‘{username[++i]=$1} END{print username[1]}’ /etc/passwd
root
# awk -F: ‘{username[i++]=$1} END{print username[1]}’ /etc/passwd 
bin
# awk -F: ‘{username[i++]=$1} END{print username[0]}’ /etc/passwd 
root

# awk -F: ‘{username[x++]=$1} END{for(i=0;i<NR;i++) print i,username[i]}’ /etc/passwd
0 root
1 bin
2 daemon
3 adm
4 lp
5 sync
6 shutdown
7 halt

# awk -F: ‘BEGIN{x=1} {user[x++]=$1} END{for(i=1;i<=NR;i++) {print i,user[i]} }’ /etc/passwd
# awk -F: ‘BEGIN{j=1} {if($3<5){user[j++]=$1}}   END{for(i=1;i<j;i++) {print i,user[i]} }’ /etc/passwd

# awk -F: ‘BEGIN{i=1} {username[i]=$1;i++}’

# awk -F: ‘BEGIN{i=1} $3<10{username[i]=$1;++i} END{for(j=1;j<i;j++){print j,username[j]}}’ /etc/passwd
等价于#awk -F: ‘BEGIN{i=1}{if($3<10){username[i]=$1;i++}}END{for(j=1;j<i;j++){print j,username[j]}}’ /etc/passwd
1 root
2 bin
3 daemon
4 adm
5 lp
6 sync
7 shutdown
8 halt
9 mail
10 admin

========================================================
# awk -F: ‘{username[++x]=$1} END{for(i=1;i<=NR;i++) {print i,username[i]}}’ passwd1 
1 root
2 bin
3 daemon
4 adm
5 lp
6 sync
7 shutdown
8 halt
9 mail
10 uucp

# awk -F: ‘{username[++x]=$1} END{for(i in username) {print username[i]} }’ passwd1 
adm
lp
sync
shutdown
halt
mail
uucp
root
bin
daemon

# awk -F: ‘{user_id[$1]=$3} END{for(i in user_id) {print i,user_id[i]}}’ passwd1 
bin 1
uucp 10
mail 8
sync 5
shutdown 6
adm 3
daemon 2
halt 7
root 0
lp 4

========================================================

统计用户名为4个字符的用户:
[root@jeson ~]# awk -F: ‘$1~/^….$/{count++; print $1} END{print “count is: ” count}’ /etc/passwd
root
sync
halt
mail
news
uucp
nscd
vcsa
pcap
sshd
dbus
jack
count is: 12

[root@jeson ~]#  awk -F: ‘length($1)==4{count++; print $1} END{print “count is: “count}’ /etc/passwd
root
sync
halt
mail
news
uucp
nscd
vcsa
pcap
sshd
dbus
jack
count is: 12

作业:
1. 取得网卡IP(除ipv6以外的所有IP)
2. 获得内存使用情况
3. 获得磁盘使用情况
4. 清空本机的ARP缓存
5. 打印出/etc/hosts文件的最后一个字段(按空格分隔)
6. 打印指定目录下的目录名

[root@jeson dir1]# arp -a |awk -F”[()]” ‘{print “arp -d”, $2}’
arp -d 192.168.2.26
arp -d 192.168.2.44
arp -d 192.168.2.28
arp -d 192.168.2.130
arp -d 192.168.2.90
arp -d 192.168.2.18
arp -d 192.168.2.129
[root@jeson dir1]# arp -a |awk -F”[()]” ‘{print “arp -d ” $2}’ |sh

[root@jeson ~]# awk -F: ‘{print $7}’ /etc/passwd
[root@jeson ~]# awk -F: ‘{print $NF}’ /etc/passwd
[root@jeson ~]# awk -F: ‘{print $(NF-1)}’ /etc/passwd

[root@jeson ~]# ll |grep ‘^d’
drwxr-xr-x 104 root root     12288 09-22 05:37 192.168.0.48
drwxr-xr-x   2 root root      4096 10-30 15:47 apache_log
drwxr-xr-x   2 root root      4096 10-30 15:23 awk
drwxr-xr-x   2 root root      4096 10-24 09:09 Desktop
drwxr-xr-x  12 root root      4096 10-08 06:12 LEMP_Soft
drwxr-xr-x   2 root root      4096 10-24 07:38 scripts
drwxr-xr-x   6 root root      4096 2012-03-29 uplayer
drwxr-xr-x   7 root root      4096 10-23 04:53 vmware
[root@jeson ~]# 
[root@Jeson ~]# awk ‘{username[i++]=$NF}END {for(j=0;j<i;j++){printf username[j]”\t”}}’ /etc/hosts
[root@jeson ~]# ll |grep ‘^d’ |awk ‘{print $NF}’
192.168.0.48
apache_log
awk
Desktop
LEMP_Soft
scripts
uplayer
vmware

awk脚本:
user1.awk
BEGIN {
        FS=”:”
}

{
        if($3==0){
                print $1
        }
        else{
                print $7
        }
}

user2.awk
BEGIN{
        FS=”:”
        OFS=”\t\t”
        print “username\tuid”
        print “——————-“
}

{if($3==0){
        print $1,$3;i++
        }

}

END{
        print “——————-“
        print “total users is: “i
}

Shell三剑客之AWK用法

Pingbacks已打开。

引用地址

暂无评论

发表评论